Registrieren    Anmelden    Suche    FAQ

Portal » Foren-Übersicht » Allgemeine Infos » alles was sonst noch wichtig ist




Ein neues Thema erstellen Auf das Thema antworten  [ 1 Beitrag ] 
Autor Nachricht
 Betreff des Beitrags: Makro guide für beginner
 Beitrag Verfasst: Fr 26. Aug 2011, 16:55 
Offline
Administrator

Registriert: So 8. Mär 2009, 00:14
Beiträge: 21
Makros

Makros gibts seit es WoW gibt aber das System wurde mit BC stark erweitert und umgebaut. Viele Macros die vor 2.0 geschrieben wurden,würden heute nicht mehr funktionieren. Vor 2.0 konnten Macros komplexe Entscheidungen im Kampf treffen,dass ist heute nicht mehr möglich. Dafür wurden eine Vielzahl an neuen slash-commands hinzugefügt,die vieles erleichtern oder verbessern. Die Idee war dass Blizzard mehr Kontrolle über die Makro-Erstellung haben wollte um Botting und Automatisierung im Spiel zu vermeiden.

Wozu gibts Makros ?

Makros erlauben dem Spieler einen Button mit mehren Aktionen/Funktionen zu belegen ohne ein Addon benutzen zu müssen. Makros können komplexere Aufgaben übernehmen,eine ganze Reihe von Casts auslösen,Texte ausspucken etc
Ein Beispiel:

/cast [nocombat,stance:1] Charge; [combat,nostance:3] Berserker Stance; [nocombat,nostance:1] Battle Stance; [combat,stance:3] Intercept

mit de-client müsste es so aussehen:

/wirken [nocombat,stance:1] Anstürmen; [combat,nostance:3] Berserkerhaltung; [nocombat,nostance:1] Kampfhaltung; [combat,stance:3] Abfangen

Was dieses Makro macht:
1. Wenn man nicht im Kampf und in Kampfhaltung ist -> Charge
2. Wenn man im Kampf und nicht in Berserk-Stance ist -> Berserk-Stance
3. Wenn man nicht im Kampf und nicht in Kampfhaltung ist -> Kampfhaltung
4. Wenn man im Kampf und in Berserker-Stance ist -> Intercept

Das alles in zwei Zeilen und auf einem Knopf,hat was oder ? Aber Vorsicht,es wird immer nur eine Aktion bzw. Zeile ausgeführt,man muss also gegebenenfalls mehrmals aufs Makro drücken.
Trotz vieler schöner Dinge die man Makros tun lassen kann sind die Möglichkeiten doch begrenzt.

Was kann man nicht mit Makros machen ?

Makros sollen den Kampf nicht Automatisieren und keine komplexeren Entscheidungen treffen,also nicht zu viel Arbeit abnehmen. Mit Entscheidungen meine ich Umstände die ein Makro auslösen bzw. unter denen das Makro bestimmte Handlungen ausführt.
Aufgrund dieser Dinge können Makros keine "Entscheidungen" treffen:

* Die Entfernung vom Spieler zu einer unit
* Die Menge an HP oder Mana die der Spieler oder eine Unit hat
* Der verbleibende Cooldown eines Spells,Items oder Aktion
* Die Anzahl der Combopunkte die der Spieler auf einem target hat
* Wenn eine bestimmter Umstand für einen Spell eintritt wie zb "Muss hinter dem Ziel sein"
* Die Buffs oder Debuffs die eine unit hat

Außerdem darf ein Makro nur 255 Zeichen lang sein,auch wenn es Mods gibt die das ändern.

Mehrere Spells mit einem Makro casten

Im Allgemeinen gilt: Ein Makro kann auch nur einen Spell auslösen (mit einmal drücken). Es sei denn,der Spell löst keinen gcd (Global cooldown) aus.
Der Global Cooldown ist ein art "Zeitraum" der Anfängt sobald man einen Spell wirkt. In diesem Zeitraum kann man keinen anderen cast wirken. Er wurde noch in der Beta eingeführt um mehr Ruhe ins Spiel zu bringen und nicht den Spieler zu bevorzugen der schneller auf seine Knöpfe drücken kann. Schurken und Druiden in Katzenform haben 1,0 sek gcd,alle anderen Klassen 1,5sek.
Es gibt Spells und Items die keinen gcd auslösen. Das sind solche die eine direkte Auswirkungen auf den folgenden Spell haben. Beispielsweise Schnelligkeit der Natur, ein Druiden und Schamanen Spell der den nächsten Naturzauber mit weniger als 10 Sekunden casttime instant wirken lässt. Wenn NS also einen gcd auslösen würde,wäre ja auch der Effekt des Spells schon halb verpufft.
Wenn man mehrere Spells in einem Makro gleichzeitig auslösen will muss man sie mit einem "/stopcasting" trennen damit der Client weiß dass noch ein Spell folgt.
zb.:

/cast Nature's Swiftness
/stopcasting
/cast Healing Touch

Hier sind Spells und Items die keinen gcd auslösen und daher direkt mit einem anderen Spell kombiniert werden können:

* Spells die,die Kosten des nächsten Spells senken oder die crit-chance erhöhn (zb Inner Focus)
* Spells die den nächsten Spell instant machen (zb Nature's Swiftness)
* Items die Heilung/Spelldamage der nächsten Spells erhöhn (zb Talisman of Ephemeral Power)
* Spells die den Cooldown von Fähigkeiten nehmen (zb Cold Snap oder Preparation)

Die Makro Syntax

Die Syntax für jede Makrozeile schaut generell so aus:

/command [conditions] spellname; [conditions2] spellname2; ...

Beispielsweise kann man ein Makro baun,das Demon Skin wenn man nicht im Kampf ist und einen Shadowbolt castet wenn man im Kampf ist:
Code:

/cast [nocombat] Demon Skin; Shadow Bolt

Der Client überprüft die erste Bedingungen (nicht im Kampf) und wenn sich diese als wahr erweist,wird der erste Spell gecastet,falls die Bedingung nicht wahr ist (im Kampf) wird der zweite Spell gecastet. Es gibt viele "Bedingungen" dieser Art,gehe ich später noch genauer darauf ein.
Allerdings braucht man gar nicht für jedes Makro eine solche Bedingung. Man kann fast alle /cmds benutzen die man auch normal im Spiel verwendet (zb /p /yell /ra etc). Für alle dieser cmds kann man "%t" als variable für "target" und "%f" für "focus" benutzen.
zb.:

/cast Polymorph
/p Ich sheepe %t !

Dieses Makro sheept das gegenwärtige Target und gibt den Namen des Ziels im grp-channel aus.

Makro Commands

Es gibt sehr viele /cmds die man in ein Makro schreiben kann. Ich liste mal die wichtigsten auf. Damit es nicht zu unübersichtlich wird teil ich sie nach Art der Funktion auf. Angaben in [ ] sind optional.

Casten, Benutzen und Angreifen

* /cast <spell> (castet einen Spell,geht auch für Pets)
* /use <itemname> (benutzt das Item)
* /use <slot> (benutzt einen Slot im Charmenü)
* /use <bagid> <bagslot> (benutzt ein Item an einer bestimmten Stelle des Inventars
* /equip <itemname> (zieht das Item an)
* /equipslot <slot> <Itemname> (zieht ein Item in einen bestimmten Slot)
* /castrandom <spell1> <spell2> (castet einen zufälligen Spell)
* /userandom <item1> <item2> (benutzt zufällig ein Item)
* /stopcasting (stoppt einen Spell)
* /startattack [unit] (greift eine bestimmte unit an)
* /stopattack (beendet den Angriff)

Targeting

* /targetenemy (nimmt den nächsten Feind ins target)
* /targetfriend (nimmt den nächsten Freund ins target)
* /targetparty (nimmt das nächste Gruppenmitglied ins target)
* /targetraid (nimmt den nächsten Raidmember ins target)
* /targetlasttarget (nimmt das letzt Ziel ins target)
* /cleartarget (löscht das target)
* /clearfocus (löscht den fokus)
* /target [UnitID oder name] (nimmt eine unit ins target)
* /focus [UnitID oder name] (setzt eine unit als fokus)
* /assist [UnitID oder Name] (unterstützt eine unit)

Viele dieser cmds kann man mit "1" umkehren, zb "/targetenemy 1 nimmt nicht den nächsten,sondern den weitest entfernten Gegner ins target.

Ein UnitID ist ein art Name den das Spiel benutzt um "Objekten" bestimmte Namen zuzuweißen.
Hier sind die wichtigsten Units:

* player (der Spieler,also du)
* pet (dein Pet,wenn aktiv)
* party1-party4 (die partymember)
* raid1-raid40 (die raidmember)
* target (dein target,falls vorhanden)
* focus (dein Fokus,falls vorhanden)
* mouseover (die unit unter deinem Mauszeiger)
* party1target (das Ziel des ersten partymembers)
* party1pet (das Pet des ersten partymembers,falls vorhanden)

Wie man an den letzten beiden Einträgen sieht kann man "target" oder "pet" an andere units dranhängen. Das lässt sich auch erweitern und verlängern zb "raid14targettarget".

Verschiedenes

* /click ButtonName [mouseButton] (drückt einen Knopf)
* /cancelaura <name> (bricht einen Buff von dir ab)
* /changeactionbar <page> (wechselt die Seiten deiner Actionbar durch)
* /swapactionbar <page1> <page2> (wechselt zwischen Seite 1 und 2)
* /stopmacro (stoppt das Makro)
* /dismount (lässt dich vom mount steigen)


Pet Actions

* /petattack (lässt dein pet angreifen)
* /petfollow (lässt dein pet folgen)
* /petstay (lässt dein pet warten)
* /petpassive [defensive,aggressive] (setzt dein Pet in den entsprechenden Modus
* /petautocason <spell> (schaltet den autocast des spells ein)
* /petautocastoff <spell> (schaltet einen autocast aus)

Makro Bedingungen

Ich beschreibe mal n paar der wichtigsten Makro-conditions mit Beispielen.

[combat] und [nocombat]
Stellt fest ob man im Kampf ist oder nicht und handelt dementsprechend.
zb.:

/cast [nocombat] Mark of the Wild; [combat] Regrowth

Ein Makro geht jede einzelne Zeile nach der anderen durch und handelt dementsprechend,das makro hier castet mdw wenn man nicht im Kampf ist und regro wenn man es ist. Allerdings kann man das [combat] in diesem Fall auch weglassen,weil immer wenn man nicht im Kampf ist,man im Kampf ist,d.h.:

/cast [nocombat] Mark of the Wild; Regrowth

geht in diesem Fall genauso.

[harm] und [help]
Die beiden conditions sind antonyme. [harm] sagt "wenn das ziel angreifbar ist" und [help] "wenn das target assistbar ist".
zb.:

/cast [harm] Moonfire; [help] Lifebloom

Wenn man jetzt noch das makro von oben dazu baut,hat man schon ein relativ komplexes und nützliches makro:

/cast [combat,help] Regrowth; [harm] Moonfire; [target=player,nocombat] Mark of the Wild

Wenn man im Kampf und das target assistbar is,heilt man es mit regro,wenn das target angreifbar ist,castet es Mondfeuer. Andernfalls buffet es dich mit mdw.

Das Komma "," bedeutet dass jede Bedinungen zutreffen muss damit das ereigniss eintritt. Sowas wie [wenn im Kampf oder assistbar] geht nicht in der selben Bedinungen,müsste es also so:

/cast [combat] Regrowth; [help] Regrowth; Moonfire

machn.
Es castet regro wenn man im Kampf ist oder einen assistbaren im target hat,ansonstn castet es Moonfire.
btw: wenn man keinen rang/rank beim spell dazuschreibt,nimmt wow immer den höchstmöglichen.

[stance],[stance:#] und [nostance]
Sowas steht schon im ersten Makro ganz am Anfang. Es betrifft alle Klassen die sowas wie "stances" habn,also warris,druis,shadowpriests und rogis.

Krieger Priester Druide Schurke
[nostance]
Normal Castergestallt Normal
[stance:0]
" " "
[stance: 1] Kampfhaltung Schattenform Bärform Stealth
[stance: 2] Verteidigungshaltung
Wasserform
[stance:3] Berserkerhaltung
Katzenform
[stance:4]

Reiseform
[stance:5]

Eule,Baum oder Flugform
[stance:6]

Flugform (wenn keine Eule oder Baum geskillt)

Die "stances" kann man auch mit /cancelaura cmd kombinieren,zb wenn man ein makro machen will,das einen drui immer in casterform bringt:

/cancelaura [stance:1] Dire Bear Form; [stance:2] Aquatic Form; [stance:3] Cat Form; [stance:4] Travel Form

Druiden haben bis zu 6 "stances". Wenn man sich ingame nicht mehr dran erinnert welche,welche nummer hatte,kann man sie einfach von links nach rechts durchzählen.

Jetzt ein Beispiel wie man die "stances" in andre makros einbauen kann. Wenn wir jetzt das druiden-makro von oben nehmen und es mit den stancen tunen kommt zb sowas raus:

/cancelaura [stance:1] Dire Bear Form; [stance:2] Aquatic Form; [stance:3] Cat Form; [stance:4] Travel Form
/cast Nature's Swiftness
/stopcasting
/cast [target=player] Healing Touch

Wenn man bereits in Castergestalt ist,heilt man sich instant und mit einmal drücken. Wenn man in irgendeinem viech ist,wird man in casterform geholt und mit dem zweiten klick geheilt.

[stealth] und [nostealth]
Einfache Bedinungen mit unterschiedlichen spells je nach dem ob man in stealth ist oder nicht.
zb.:

/cast [stealth] Ambush; Backstab

Wenn man im stealth is macht man Ambush,wenn nicht Backstab.

[mounted] und [nomounted]
kontrolliert ob man auf einem mount sitzt oder nicht. Ebenso kann man sich auch vom mount nehmen indem man den "mount-buff" canceld:

/cancelaura [mounted] Grey Riding Kodo

[swimming] und [noswimming]
Beispielsweise für druiden intressant weil sie eine Wasserform habn. Könnte sowas machn:

/cast [swimming] Aquatic Form; Travel Form

Wenn man grad am schwimmen ist,kommt man in die wasserform,ansonstn in die Reiseform. Könnte sich zb auch Unterwasseratmung buffen etc

[flying] und [noflying]
kann man natürlich auch mit /cancelaura kombiniern,zb.:
Code:

/cancelaura [noflying] Flight Form

kann damit die fluggestalt entfernen wenn man nicht grade fliegt.

[indoors] und [outdoors]
praktisch zb für Jäger:

/cast [indoors] Aspekt des Geparden; Grüner Raptor

innen schmeißt man den Aspekt an,draußen das mount.

[modifier],[modifier<:shift|ctrl|alt] und [nomodifier]
Die modifier-Bedingung ermöglicht es bestimmte Teile im Makro nur auszulösen wenn bestimmte Tasten gedrückt werden. Als modifier stehen zu verfügung: shift,strg,alt und Kombination aus diesen,andere Tasten sind nicht möglich.

/cast [modifier:shift] Gift of the Wild; Mark of the Wild

Wenn man jetzt drauf drückt und shift hält,wird GdW gecastet und wenn nicht MdW.
Wie gesagt lassen sich die modifier auch kombinieren:

/cast [modifier:alt, modifier:strg] Mage Armor; [modifier:shift] Arcane Brilliance; Arcane Intellect

Drückt man ohne alles,castet es int,mit shift grp-int und bei alt+strg-click die Rüstung.
Will man ein "oder" bei den modifiern schreiben,weil man zb schlicht nicht mehr weiß welchen man genommen hat,kann man das mit einem "/" ausdrücken:

/cast [modifier:alt/shift/strg] Gift of the Wild; [nomodifier] Mark of the Wild

Wenn man jetzt irgendeine Taste drückt kommt der grp-buff und ohne jeder der singel-buff.
Das geht aber auch kürzer und einfacher. Statt "[modifier:alt/strg/shift]" kann man auch schlicht "[modifier]" schreiben nach dem motto "wenn irgendein modifier gedrückt ist".

[equipped:<slot>|<class>|<subclass>]
Damit lassen sich Bedingungen aufstellen je nach dem welches item equipped ist. Bei einem rogi zb:

/cast [equipped:Dagger] Ambush; Cheap Shot

Wenn man also einen Dolch angelegt hat -> Ambush und wenn nicht -> Cheap Shot.
Das geht mit jeder "Itemklasse".die steht oben rechts im Tooltip. Geht natürlich auch mit Itemnamen.

[actionbar:<page>]
damit kann man actionbar-seiten wechseln. zb:

/changeactionbar [combat,actionbar:1] 3; [nocombat, actionbar:1] 4; 1

Das macht dann folgendes:
1. Wenn man im Kampf ist und die Seite 1 aktiv ist -> Wechsel zu Seite 3
2. Wenn man nicht im Kampf ist und auf Seite 1 -> Wechsel zu Seite 4
3. Wenn man auf irgendeiner andren Seite ist -> Wechsel zur Seite 1

Das ermöglicht einen die Leisten für bestimmte Situationen zu definieren und mit einem einzelnen drücken zwischen ihnen zu wechseln, zb auf Seite 1 sind generelle Funktionen und Fähigkeiten,auf Seite 3 die Kampffähigkeiten und in 4 die Nicht-Kampf-Fähigkeiten.

[button] und [nobutton]
Damit sind die Mausbutton gemeint,also sie als modifier einzusetzen.

Linker Mausbutton -> 1
Rechter Mausbutton -> 2
Mittlerer Mausbutton (Rad) -> 3
Daumentaste -> 4
5. Taste -> 5

Soweit ich weiß gehen nur Buttons von 1-5,aber 6-Tasten-Mäuse gibt es eh nicht so viele^^
Ein Beispiel wie man sowas anwenden kann:

/cast [button:1] Mark of the Wild; [button:2] Gift of the Wild

Bei links-click castet es mdw,bei rechtsklick gdw.

[pet:<name>|<type>] und [nopet]
Damit kann man verschiedene Dinge auslösen je nach dem welches Pet aktiv ist.
zb:

/cast [pet:Owl] Dive; [pet:Cat] Dash; [pet] Growl

Man kann auch statt der Petart den Namen verwenden.
für Hexer:

/cast [pet:Voidwalker] Sacrifice; [pet:Succubus] Seduction

Mit [nopet] kann man dann Dingen auslösen,wenn kein pet aktiv ist.

[channeling],[channeling:<spell>] und [nochanneling]
Damit können events ausgelöst werden wenn man gerade etwas kanalisiert oder eben nicht.
zb.:

/cast [nochanneling:Evocation] Ice Block

damit wird der Eisblock nur ausgelöst wenn nicht grad evo am channeln ist. Oder man kann verhindern,dass Arkane Geschosse nicht gestartet werden,wenn sie schon am laufen sind:

/cast [nochanneling: Arcane Missiles] Arcane Missiles

[exists] und [noexists]
Damit werden Spells etc nur ausgelöst wenn zb das Target existiert. Oder man kann damit den mt heilen ohne den Boss aus dem Target nehmen zu müssen:

/cast [help] Regrowth; [target=targettarget,exist,help] Regrowth

Wenn dein Ziel freundlich ist,wird regro gecastet,andernfalls wird das target des targets geheilt wenn es existiert und freundlich ist.

[dead] und [nodead]
War neulich hier im Forum das Problem dass jemand auch tote Ziele ins target bekommen hat,mit den beiden conditions lässt sich das verhindern. Oder auch zb für Jäger:

/cast [target=pet,exists,dead] Revive Pet; [target=pet,exists] Mend Pet; [target=pet,noexists] Call Pet

Das Makro versucht dein Pet zu rezzen falls es tot ist,heilt es wenn es am leben ist und ruft es wenn es nicht aktiv ist.

[party] und [raid]
Gecastet wird nur,wenn das Ziel in deinem Raid oder Party ist. Vielleicht nützlich zum buffen:

/cast [party,noraid] Gift of the Wild; Mark of the Wild

[group:<party|raid>]
Diesmal wird gecheckt ob du selbst in Raid oder Party bisd.

Die "neuen" BC-Commands
Mit 2.0 kamen jede Menge neue /cmds dazu. Sind vielleicht sogar die schönsten.

/use <itemname>, /use <slot> und /use <bagid> <slotid>
Damit lassen sich Items nahezu überall zu verschiedenen Bedingungen benutzen.
Zum Beispiel nach name:

/use Manapot

oder nach slot-nummer:

/use 13

(13 und 14 sind die Trinquetslots)
oder nach ihrem Platz im Iventar:

/use 0 0

(bag 0 ist der Rucksack und slot 0 das item in der unteren linken Ecke)

Außerdem werden Items mit /use nicht nur benutzt sondern auch noch angelegt,falls dass nicht der Fall ist:

/use Insignia of the Horde

(beim ersten drücken wirds angelegt und mit dem zweiten benutzt. Nicht vergessen dass Items einen cd haben wenn man sie gerade erst angelegt hat.)

/equip <itemname> und /equipslot <slot> <itemname>
legt ein Item an,falls gewünscht in einen bestimmten Slot (Man hat zwei Trinqui-slots^^).
zb.:

/equip Insignia of the Horde

Was auch schön ist: wenn man nur ein Item hat dessen Name so anfängt kann man es im Makro auch abkürzen:

/equip Insignia

Wenn man ein Item in einen bestimmten Slot legen will:

/equipslot 13 Insignia of the Horde

/castrandom <spell1>, <spell2>, <spell3>
Damit lassen sich zufällig Spells auswählen,zb.:

/castrandom Polymorph,Pyroblast

(Bitte nicht verwenden^^) oder:

/castrandom [nochanneling] Tranquility, Regrowth, Healing Touch

Aber vorsicht: das makro kontrolliert keine Cooldowns,das heißt wenn der zufällig ausgewählte Spell cd hat,wird nichts gecastet.

/userandom <itemname1>, <itemname2>, <itemname3>
Wählt zufällig Items aus,zb.:

/userandom [nomounted] Grey Kodo, Brown Kodo, Black Kodo
/dismount [mounted]

wählt zufällig ein mount aus dass man dabei hat und wirft einen vom mount wenn man reitet.

/stopcasting
Funktioniert fast wie das alte "/script SpellStopCasting()". Es ermöglicht einen mehrere Spells mit einem Makro auszulösen,wenn das erste keinen gcd auslöst (siehe oben).
Außerdem kann man "/stopcasting" benutzen um einen Spell abzubrechen,zb einen Heal.

/stopmacro
Damit lässt sich ein Makro abbrechen wenn bestimmte Bedinungen eintreffen,zum Beispiel als rezzer:

/cast Reszrrection
/stopmacro [noexists]
/stopmacro [nodead]
/say Rezze %t...

Man wählt ein Target,rezzt und sagt es an. Wenn aber das Ziel den Geist freigelassen hat und man den Spieler "mit der Hand" suchen muss,wird der Name des targets nicht genannt,weil es in diesem Fall auch nur ein "<kein Ziel>" ausspucken würde.

/click <Buttonname> <buttonNumber>
Damit kann man mit einem Makro einen Knopf ohne die Maus drücken. Das ist dann nützlich wenn man eine bestimmte Fähigkeit in Leiste 3 aktivieren will,aber gerade Leiste 1 aktiv ist.
Mit dem diesem Makro:

/click ActionButton10 2

wird mit rechts auf den zehnten Knopf,unabhängig von der gerade aktiven Seite.
Das gilt nicht nur für die Actionbar,sondern für alle "Knöpfe" im Spiel,auch die von Blizzard.
Damit zb.:

/click [modifier:alt] MinimapZoomOut; MinimapZoomIn

zommt man die Minimap heraus wenn man alt drückt und herein wenn man nichts drückt. Zwar kann man das auch in der Tastaturbelegung auf eine Taste binden,wollte aber damit zeigen was alles möglicht ist.

/cancelaura <buffname>
hatten wir schon. Es bricht buffs ab und alles was wie ein buff ist,zb mounts oder die Formen des Druiden.

/changeactionbar
hatten wir auch schon. Damit kann man die Leisten wechseln.

/swapactionbar <page1> <page2>
Switcht zwischen zwei bestimmten Bars.

Kommentare in Makros

Man kann in Makros genauso wie in Mods Kommentare hinterlassen. Damit diese vom Makro ignoriert werden kann man "-" oder "#" davor schreibn und die Zeile wird übergangen:

- Heilt dein Pet wenn es aktiv ist
/cast [target=pet,exists] Mend Pet
# ruft dein pet wenn es nicht da ist
/cast [target=pet,noexists] Call Pet

Icons, Tooltips und Cooldowns

Ebenfalls mit 2.0 eingeführt wurde das "?" als Makro-Icon (gleich das erste). Das ist ein mehr als nur nützliches ding. Wählt man es als Symbol aus,stellt es das Icon und den Tooltip des erste Spells/Items da,das im Makro ist.
Nun kann es aber passieren dass man gar nicht den Tooltip des ersten,sondern des zweiten spells sehen will (zb wegen dem cd darauf,wegen der range etc). Dafür benutzt man "#showtooltip <name>". Damit kann man sich jeder Tooltip anzeigen lassen den man will.
zb.:

#showtooltip Healing Touch
/cast Nature's Swiftness
/stopcasting
/cast [target=mouseover] Healing Touch

Cast-Sequenzen

Damit lässt sich ein Makro erstellen,dass eine Reihe von Spells casten lässt. Die Syntax schaut generell so aus:
Code:

/castsequence [<options>] reset=<conditions> <spell1>, <spell2>, <spell3>

Das "reset"en machen wir später,erstmal das Grundmodel. Ein Hexer-Makro könnte zb so aussehen:

/castsequence Corruption, Immolate, Curse of Agony

Sobald ein cast erfolgreich war,"wandert" das Makro zum nächsten. Damit wird das ganze dot-Programm auf eine Taste gelegt.
Wenn man jetzt noch das "?" als icon wählt,wird immer der nächste Spell der gecastet wird angzeigt.

Die Reset Bedingungen

Nun könnte es passieren,dass man die Spellschlange reseten will,zb weil man ein neues target hat. Dafür baut man dann eine von diesen resets ein:

* <num> Hier kann man eine Anzahl von Sekunden eintragen
* target Resetet das Makro wenn das Ziel gewechselt oder verloren wird
* combat Resetet wenn man in einen Kampf kommt oder ihn verlässt
* alt/strg/shift Resetet wenn einer dieser Knöpfe gedrückt wird

Die Bedingungen lassen sich wie immer auch kombinieren. Dafür benutzt man "/".
Wenn man also so ein Makro baut:

/castsequence reset=target/combat Corruption, Curse of Agony, Fear, Immolate

wird das Makro immer resetet wenn du das Ziel wechselst, es verlierst oder den Kampf verlässt.
Man kann auch den reset auf eine bestimmte Zeit festlegen,zb wenn ein cooldown abgelaufen ist:

/castsequenz reset=24 Frost Nova, Blink


Nach oben 
 Profil
Mit Zitat antworten  
 Betreff des Beitrags:
  Verfasst: Fr 26. Aug 2011, 16:55 
 


Nach oben 
 
 
Beiträge der letzten Zeit anzeigen:  Sortiere nach  
 
Ein neues Thema erstellen Auf das Thema antworten  [ 1 Beitrag ] 

Portal » Foren-Übersicht » Allgemeine Infos » alles was sonst noch wichtig ist


Wer ist online?

0 Mitglieder

 
 

Tags

Auto, Bau, Laufen, Mode, Programm, Spiele, WOW

 
Du darfst keine neuen Themen in diesem Forum erstellen.
Du darfst keine Antworten zu Themen in diesem Forum erstellen.
Du darfst deine Beiträge in diesem Forum nicht ändern.
Du darfst deine Beiträge in diesem Forum nicht löschen.
Du darfst keine Dateianhänge in diesem Forum erstellen.

Suche nach:
Gehe zu:  
cron




Bei iphpbb3.com bekommen Sie ein kostenloses Forum mit vielen tollen Extras
Forum kostenlos einrichten - Hot Topics - Tags
Beliebteste Themen: Erde, Spiele, NES, Bau, WOW

Impressum | Datenschutz